Return to Maxima で理工系の数学C

Maxima でフーリエ解析

フーリエ級数

  1. 区間 $-\pi < x < \pi$ で定義された関数 $f(x)$ は,それがどんな関数であっても…
  2. 区間外では,周期 $ 2\pi $ の周期関数とみなして
  3. 三角関数 $\cos, \ \sin$ の重ね合わせて表すことができる!

つまり,以下のように書けるということ。

$$ f(x) = \frac{a_0}{2} + \sum_{n=1}^{\infty} \bigl( a_n \cos n x + b_n \sin nx \bigr) $$

ここで,フーリエ係数 $a_n, b_n$ は

$$a_n = \frac{1}{\pi} \int_{-\pi}^{\pi} f(x) \cos nx \, dx $$$$b_n = \frac{1}{\pi} \int_{-\pi}^{\pi} f(x) \sin nx \, dx $$

例題

区間 $[-\pi: \pi]$ で定義された関数 $f(x) = x^2$ のフーリエ級数展開。

周期 $2 \pi$ の周期関数として,

  • $[-3\pi:-\pi]$ では $f(x) = (x+2 \pi)^2$…
  • $[-\pi:\pi]$ では $f(x) = x^2$,
  • $[\pi:3\pi]$ では $f(x) = (x-2 \pi)^2$…

のようにすればいい。

まず,1周期分の $f_0(x) \equiv x^2$ を定義して,$[-\pi:\pi]$ の区間でグラフを描く。

In [1]:
f0(x):= x**2;
Out[1]:
\[\tag{${\it \%o}_{1}$}f_{0}\left(x\right):=x^2\]
In [2]:
plot2d(f0(x), [x, -%pi, %pi])$

$[-\pi:\pi]$ の区間外では,周期 $2 \pi$ の周期関数として,

  • $[-3\pi:-\pi]$ では $f(x) = (x+2 \pi)^2$…
  • $[-\pi:\pi]$ では $f(x) = x^2$,
  • $[\pi:3\pi]$ では $f(x) = (x-2 \pi)^2$…

をグラフに描くために,ちょっと工夫をします。(詳細は省きますが,$x$ の異なる範囲ごとに異なる関数のグラフを重ねて描くため,媒介変数表示 parametric でプロットしています。)

In [3]:
plot2d([parametric, t, f0(t), [t, -%pi, %pi]], 
       [x, -3*%pi, 3*%pi]
)$

In [4]:
plot2d([[parametric, x, f0(x + 2*%pi), [x, -3*%pi, -%pi]],
        [parametric, x, f0(x),         [x,   -%pi,  %pi]],
        [parametric, x, f0(x - 2*%pi), [x,    %pi, 3*%pi]]
       ], [x, -3*%pi, 3*%pi]
)$

周期毎に別の関数を描くのは面倒なので,切り捨てる関数 floor() を使って周期 $2\pi$ の関数 $f(x)$ を定義します。

In [5]:
f(x):=  f0(x - 2*%pi*floor((x+%pi)/(2*%pi)));
Out[5]:
\[\tag{${\it \%o}_{8}$}f\left(x\right):=f_{0}\left(x-2\,\pi\,\left \lfloor \frac{x+\pi}{2\,\pi} \right \rfloor\right)\]

何これ?と思った人もいるかもしれないが,実際にグラフを描くと確かに周期関数になっていることがわかる。

関数 $f(x)$ を $a \leq x \leq b$ の範囲でグラフにするのは,Maxima では以下のように書く。

plot2d(f(x), [x, a, b]);

上で定義した周期関数 $f(x)$ を $-3\pi \leq x 3\pi$ の範囲でグラフを描くには…

In [6]:
plot2d(f(x), [x, -3*%pi, 3*%pi])$

少しオプションを設定して描く例:

以下の例では,

  1. legend で凡例を設定し,
  2. [y, -2, 12] で縦軸の表示範囲を設定し,
  3. grid2d でグリッド(格子線)を表示させる設定をし,
  4. [ylabel, ""] で $y$ 軸のラベルをカラにし,
  5. [xtics, %pi] で $x$ 軸の目盛りを $\pi$ ごとにし,
  6. $x$ 軸のフォーマットを $\pi$ の倍数になるように設定しています。
In [7]:
plot2d(f(x), [x, -3*%pi, 3*%pi], [legend,"f(x)"], [y, -2, 12], 
       grid2d, [ylabel, ""], 
       [xtics, %pi], [gnuplot_preamble, "set format x '%4.1P π'"]
)$

参考までに,draw2d() で描く例。

In [8]:
draw2d(
  yrange = [-2, 12], grid = true,
  xtics = %pi, user_preamble = "set format x '%4.1P π'",
  
  key = "f(x)", 
  explicit(f(x), x,  -3*%pi, 3*%pi)
)$

フーリエ級数は,以下のように書けました。

$$ f(x) = \frac{a_0}{2} + \sum_{n=1}^{\infty} \bigl( a_n \cos n x + b_n \sin nx \bigr) $$

ここで,フーリエ係数 $a_n, b_n$ は

$$a_n = \frac{1}{\pi} \int_{-\pi}^{\pi} f(x) \cos nx \, dx $$$$b_n = \frac{1}{\pi} \int_{-\pi}^{\pi} f(x) \sin nx \, dx $$

Maxima にはフーリエ級数を扱うパッケージ(load(fourie)$)がありますが,簡単なので,積分と和をとる演算を以下のように定義してしまいます。

In [9]:
/* フーリエ係数の定義と計算。フーリエ級数の定義。*/

a(n):= 1/%pi * integrate(f0(x)*cos(n*x), x, -%pi, %pi);
b(n):= 1/%pi * integrate(f0(x)*sin(n*x), x, -%pi, %pi);

Fourier(n, x):= a(0)/2 + sum(a(i)*cos(i*x) + b(i)*sin(i*x), i, 1, n);
Out[9]:
\[\tag{${\it \%o}_{15}$}a\left(n\right):=\frac{1}{\pi}\,{\it integrate}\left(f_{0}\left(x\right)\,\cos \left(n\,x\right) , x , -\pi , \pi\right)\]
Out[9]:
\[\tag{${\it \%o}_{16}$}b\left(n\right):=\frac{1}{\pi}\,{\it integrate}\left(f_{0}\left(x\right)\,\sin \left(n\,x\right) , x , -\pi , \pi\right)\]
Out[9]:
\[\tag{${\it \%o}_{17}$}{\it Fourier}\left(n , x\right):=\frac{a\left(0\right)}{2}+{\it sum}\left(a\left(i\right)\,\cos \left(i\,x\right)+b\left(i\right)\,\sin \left(i\,x\right) , i , 1 , n\right)\]

ちなみに,上のセルの定義で使われている関数 integrate() は積分を実行し, sum() は和をとり,説明は以下の通りです。

$\displaystyle \int_a^b f(x)\, dx = $ integrate(f(x), x, a, b);

$\displaystyle \sum_{i = 1}^n a_i = $ sum(a(i), i, 1, n);

$f(x) = x^2$ は偶関数なので,奇関数部分のフーリエ係数である $b_n$ はゼロのはず。実際に調べてみると…

In [10]:
declare(n, integer)$

b(1);
b(2);
b(3);

b(n);
Out[10]:
\[\tag{${\it \%o}_{19}$}0\]
Out[10]:
\[\tag{${\it \%o}_{20}$}0\]
Out[10]:
\[\tag{${\it \%o}_{21}$}0\]
Out[10]:
\[\tag{${\it \%o}_{22}$}0\]
In [11]:
a(0);
a(1);
a(2);
a(3);

a(n);
Out[11]:
\[\tag{${\it \%o}_{23}$}\frac{2\,\pi^2}{3}\]
Out[11]:
\[\tag{${\it \%o}_{24}$}-4\]
Out[11]:
\[\tag{${\it \%o}_{25}$}1\]
Out[11]:
\[\tag{${\it \%o}_{26}$}-\frac{4}{9}\]
Out[11]:
\[\tag{${\it \%o}_{27}$}\frac{4\,\left(-1\right)^{n}}{n^2}\]

$n = 1, 2, 3, 4$ までのフーリエ級数展開をそれぞれ,f1, f2, f3, f4 としてみます。

In [12]:
f1: Fourier(1, x);
f2: Fourier(2, x);
f3: Fourier(3, x);
f4: Fourier(4, x);
Out[12]:
\[\tag{${\it \%o}_{28}$}\frac{\pi^2}{3}-4\,\cos x\]
Out[12]:
\[\tag{${\it \%o}_{29}$}\cos \left(2\,x\right)-4\,\cos x+\frac{\pi^2}{3}\]
Out[12]:
\[\tag{${\it \%o}_{30}$}-\frac{4\,\cos \left(3\,x\right)}{9}+\cos \left(2\,x\right)-4\,\cos x+\frac{\pi^2}{3}\]
Out[12]:
\[\tag{${\it \%o}_{31}$}\frac{\cos \left(4\,x\right)}{4}-\frac{4\,\cos \left(3\,x\right)}{9}+\cos \left(2\,x\right)-4\,\cos x+\frac{\pi^2}{3}\]

それぞれの次数までのフーリエ級数展開の式と,もとの周期関数 $f(x)$ を重ねてグラフにします。

In [13]:
plot2d([f(x), f1], [x, -3*%pi, 3*%pi], [legend,"f(x)", "n=1"], 
       [y, -2, 12], 
       grid2d, [ylabel, ""], 
       [xtics, %pi], [gnuplot_preamble, "set format x '%4.1P π'"]
)$

$n = 2, 3, 4, \dots$ についても,上のようなグラフを描いてみます。

In [14]:
plot2d([f(x), f4, f3, f2, f1], [x, -3*%pi, 3*%pi], 
       [legend,"f(x)", "n=4", "n=3", "n=2", "n=1"], 
       [y, -2, 12], 
       grid2d, [ylabel, ""], 
       [xtics, %pi], [gnuplot_preamble, "set format x '%4.1P π'"]
)$

任意の周期をもつ関数のフーリエ級数展開

周期 $2\pi$ の決め打ちのフーリエ級数ではなく,任意の周期をもつ場合は,一般に周期を $2L$ として…

$$ f(x) = \frac{a_0}{2} + \sum_{n=1}^{\infty} \bigl( a_n \cos \frac{n\pi x}{L} + b_n \sin \frac{n\pi x}{L} \bigr) $$$$a_n = \frac{1}{L} \int_{-L}^{L} f(x) \cos \frac{n\pi x}{L} \, d{x} $$$$b_n = \frac{1}{L} \int_{-L}^{L} f(x) \sin \frac{n\pi x}{L} \, d{x} $$

例題

区間 $[-1:1]$ で定義された関数 $f(x) = x$ が,区間外では周期 $2$ の周期関数であるとして,$n=5$ までのフーリエ級数展開を求める。

上記の式で $L = 1$ とすればよいから…

In [15]:
kill(x, L)$
xcyc(x, L):= x - 2*L*floor((x+L)/(2*L));
Out[15]:
\[\tag{${\it \%o}_{37}$}{\it xcyc}\left(x , L\right):=x-2\,L\,\left \lfloor \frac{x+L}{2\,L} \right \rfloor\]

1区間1周期で $f_0(x)$ として定義された関数を,その区間外で周期 $2L$ の周期関数にするには,上記のような $x_{\rm cyc}$ を使えばよい。

In [16]:
f0(x):= x;
f(x):= f0(xcyc(x, 1));
Out[16]:
\[\tag{${\it \%o}_{38}$}f_{0}\left(x\right):=x\]
Out[16]:
\[\tag{${\it \%o}_{39}$}f\left(x\right):=f_{0}\left({\it xcyc}\left(x , 1\right)\right)\]
In [17]:
plot2d(f(x), [x, -5, 5], [xtics, 1])$

In [18]:
a(n):= 1/L * integrate(f0(x)*cos(n*%pi*x/L), x, -L, L);
b(n):= 1/L * integrate(f0(x)*sin(n*%pi*x/L), x, -L, L);

Fourier(n, x):= a(0)/2 + sum(a(i)*cos(i*%pi*x/L) + 
                             b(i)*sin(i*%pi*x/L), i, 1, n);
L: 1$
Out[18]:
\[\tag{${\it \%o}_{42}$}a\left(n\right):=\frac{1}{L}\,{\it integrate}\left(f_{0}\left(x\right)\,\cos \left(\frac{n\,\pi\,x}{L}\right) , x , -L , L\right)\]
Out[18]:
\[\tag{${\it \%o}_{43}$}b\left(n\right):=\frac{1}{L}\,{\it integrate}\left(f_{0}\left(x\right)\,\sin \left(\frac{n\,\pi\,x}{L}\right) , x , -L , L\right)\]
Out[18]:
\[\tag{${\it \%o}_{44}$}{\it Fourier}\left(n , x\right):=\frac{a\left(0\right)}{2}+{\it sum}\left(a\left(i\right)\,\cos \left(\frac{i\,\pi\,x}{L}\right)+b\left(i\right)\,\sin \left(\frac{i\,\pi\,x}{L}\right) , i , 1 , n\right)\]

$f_0(x) = x$ は奇関数なので,偶関数部分のフーリエ係数である $a_n$ はゼロのはず。実際に調べてみると…

In [19]:
a(0);
a(1);
a(2);
a(3);

a(n);
Out[19]:
\[\tag{${\it \%o}_{46}$}0\]
Out[19]:
\[\tag{${\it \%o}_{47}$}0\]
Out[19]:
\[\tag{${\it \%o}_{48}$}0\]
Out[19]:
\[\tag{${\it \%o}_{49}$}0\]
Out[19]:
\[\tag{${\it \%o}_{50}$}0\]
In [20]:
b(1);
b(2);
b(3);

b(n);
Out[20]:
\[\tag{${\it \%o}_{51}$}\frac{2}{\pi}\]
Out[20]:
\[\tag{${\it \%o}_{52}$}-\frac{1}{\pi}\]
Out[20]:
\[\tag{${\it \%o}_{53}$}\frac{2}{3\,\pi}\]
Out[20]:
\[\tag{${\it \%o}_{54}$}-\frac{2\,\left(-1\right)^{n}}{\pi\,n}\]
In [21]:
f1: Fourier(1, x);
f5: Fourier(5, x);
Out[21]:
\[\tag{${\it \%o}_{55}$}\frac{2\,\sin \left(\pi\,x\right)}{\pi}\]
Out[21]:
\[\tag{${\it \%o}_{56}$}\frac{2\,\sin \left(5\,\pi\,x\right)}{5\,\pi}-\frac{\sin \left(4\,\pi\,x\right)}{2\,\pi}+\frac{2\,\sin \left(3\,\pi\,x\right)}{3\,\pi}-\frac{\sin \left(2\,\pi\,x\right)}{\pi}+\frac{2\,\sin \left(\pi\,x\right)}{\pi}\]
In [22]:
plot2d([f(x), f1], [x, -5, 5], [legend, "f(x)", "n = 1"], 
       [y, -1.3, 1.3], grid2d
)$

$n = 2, 3, \dots$ の場合についてもグラフを描いてみます。

In [23]:
plot2d([f(x), Fourier(3, x), Fourier(2,x), Fourier(1, x)], 
       [x, -5, 5], 
       [legend, "f(x)", "n = 3", "n = 2", "n = 1"], 
       [y, -1.3, 1.8], grid2d
)$

フーリエ積分・フーリエ変換

任意の周期 $2L$ をもつ関数の複素フーリエ級数展開を,非周期的現象にまで拡張したものが「フーリエ積分」であり,フーリエ係数の拡張が「フーリエ変換」。

周期性のない関数に対する(連続極限としての)フーリエ積分

$$ f(x) = \frac{1}{2\pi} \int_{-\infty}^{\infty}\ F(k)\ e^{i k x}\ dk, \quad F(k) \equiv \int_{-\infty}^{\infty} f(x) \ e^{-i k x} \ dx $$

例題

以下の周期性のない関数 $f(x)$ のフーリエ変換 $F(k)$ を求めよ。

$$ f(x) = \begin{cases}
\frac{1}{a} & (|x| \leq \frac{a}{2}) \\
0 & (|x|> \frac{a}{2})
\end{cases}$$

次に,以下の極限を求めよ。$$ \lim_{a \rightarrow 0} F(k) =?$$

もし $\displaystyle |x| \leq \frac{a}{2}$ なら $\displaystyle \frac{1}{a}$ を返し,それ以外なら $0$ を返す関数 $f(x)$ の定義の例です。念のため block() で囲みます。

In [24]:
kill(a)$
f(x, a):= block(if abs(x) <= a/2 then 1/a else 0);
Out[24]:
\[\tag{${\it \%o}_{62}$}f\left(x , a\right):=\mathbf{block}\;\left(\mathbf{if}\;\left| x\right| \leq \frac{a}{2}\;\mathbf{then}\;\frac{1}{a}\;\mathbf{else}\;0\right)\]
In [25]:
/* グラフを描くために a = 2 としてみる。*/
plot2d(f(x, 2), [x, -5, 5], [y, -0.5, 1])$

$$ F(k) = \int_{-\infty}^{\infty} f(x) \ e^{-i k x} \ dx = \int_{-\frac{a}{2}}^{\frac{a}{2}} \frac{1}{a}\ e^{-i k x} \ dx$$ということを使って,フーリエ変換の無限積分を有限区間の積分にします。

In [26]:
F: integrate(1/a * exp(-%i*k*x), x, -a/2, a/2);
Out[26]:
\[\tag{${\it \%o}_{65}$}\frac{\frac{i\,e^ {- \frac{i\,a\,k}{2} }}{k}-\frac{i\,e^{\frac{i\,a\,k}{2}}}{k}}{a}\]

参考: demoivre() 関数。

In [27]:
exp(%i * x) = demoivre(exp(%i * x));
Out[27]:
\[\tag{${\it \%o}_{66}$}e^{i\,x}=i\,\sin x+\cos x\]
In [28]:
demoivre(F);
Out[28]:
\[\tag{${\it \%o}_{67}$}\frac{\frac{i\,\left(\cos \left(\frac{a\,k}{2}\right)-i\,\sin \left(\frac{a\,k}{2}\right)\right)}{k}-\frac{i\,\left(i\,\sin \left(\frac{a\,k}{2}\right)+\cos \left(\frac{a\,k}{2}\right)\right)}{k}}{a}\]
In [29]:
ans: expand(%);
Out[29]:
\[\tag{${\it \%o}_{68}$}\frac{2\,\sin \left(\frac{a\,k}{2}\right)}{a\,k}\]
In [30]:
'limit(ans, a, 0) = limit(ans, a, 0);
Out[30]:
\[\tag{${\it \%o}_{69}$}\frac{2\,\left(\lim_{a\rightarrow 0}{\frac{\sin \left(\frac{a\,k}{2}\right)}{a}}\right)}{k}=1\]

算数の問題として,

$$ \lim_{a \rightarrow 0} F(k) = \lim_{a \rightarrow 0} \frac{\sin\frac{ak}{2}}{\frac{ak}{2}} = 1$$

となることはわかった。では,フーリエ変換 $F(k)$ が $1$ となる $f(x)$ とはどのような関数であろうか。

以下のグラフから推察されるように,$a$ の値を小さくしていくと $f(x)$ は $x = 0$ の近くでのみ値をもつ関数になる。

$\displaystyle \int_{-\infty}^{\infty} f(x)\, dx =\int_{-\frac{a}{2}}^{\frac{a}{2}} \frac{1}{a} \,dx = 1$ という面積を保ちながら,$a \rightarrow 0$ で幅 $a$ がどんどん狭くなっていくため,高さ $\displaystyle \frac{1}{a}$ がどんどん高くなっていきます。

In [31]:
plot2d([f(x, 0.1), f(x, 0.2), f(x, 0.5), f(x, 2)], 
       [x, -5, 5], [y, -0.5, 10], 
       [legend, "a=0.1", "a=0.2", "a=0.5", "a=2"]
)$

この関数 $f(x)$ の $a \rightarrow 0$ の極限は,「デルタ関数」$\delta(x)$ と呼ばれます。定義は,(フーリエ変換 $F(k)$ が $1$ であるフーリエ積分であるから)

$$\delta(x) \equiv \frac{1}{2\pi} \int_{-\infty}^{\infty} e^{i k x}\ dk$$

デルタ関数は以下のような性質を持ちます。

$$\delta(x) = 0, \ \mbox{if $x \neq 0$}$$$$\int_{-\infty}^{\infty} g(x) \delta(x – c)\, dx = g(a)$$

特に,

$$\int_{-\infty}^{\infty} \delta(x)\, dx = 1$$

参考:fourie パッケージを使う場合

Maxima の fourie パッケージを使ってフーリエ級数展開を行うには,最初に一度,load() します。

In [32]:
load("fourie")$ /* パッケージ名注意! fourier ではない。*/

fourie パッケージでは $\cos$ の係数の $a_0$ の定義が以下のように $1/2$ だけ異なることに注意。

$$ f(x) = a_0 + \sum_{n=1}^{\infty} \bigl( a_n \cos n x + b_n \sin nx \bigr) $$

-- Function: fourier (<f>, <x>, <p>)

     Returns a list of the Fourier coefficients of '<f>(<x>)' defined on
     the interval '[-p, p]'.

-- Function: totalfourier (<f>, <x>, <p>)

     Returns 'fourexpand (foursimp (fourier (<f>, <x>, <p>)), <x>, <p>,
     'inf)'.

例題

まず,1周期分の関数 $f_0(x)$ を定義する。

In [33]:
f0(x):= x**2;
Out[33]:
\[\tag{${\it \%o}_{73}$}f_{0}\left(x\right):=x^2\]

$[-\pi: \pi]$ で定義された$f_0(x)$ が,区間外では周期 $2\pi$ の周期関数としたときのフーリエ係数を求めるには,関数 fourier(f0(x), x, %pi) を使う。

In [34]:
/* すでに宣言済みだが,あらためて */
declare(n, integer)$

/* フーリエ係数を求める */
ans1: fourier(f0(x), x, %pi)$

/* ∞までの全展開を表示。fourier との重複表示も。 */
totalfourier(f0(x), x, %pi);
\[\tag{${\it \%t}_{75}$}a_{0}=\frac{\pi^2}{3}\]
\[\tag{${\it \%t}_{76}$}a_{n}=\frac{4\,\left(-1\right)^{n}}{n^2}\]
\[\tag{${\it \%t}_{77}$}b_{n}=0\]
\[\tag{${\it \%t}_{78}$}a_{0}=\frac{\pi^2}{3}\]
\[\tag{${\it \%t}_{79}$}a_{n}=\frac{4\,\left(-1\right)^{n}}{n^2}\]
\[\tag{${\it \%t}_{80}$}b_{n}=0\]
\[\tag{${\it \%t}_{81}$}a_{0}=\frac{\pi^2}{3}\]
\[\tag{${\it \%t}_{82}$}a_{n}=\frac{4\,\left(-1\right)^{n}}{n^2}\]
\[\tag{${\it \%t}_{83}$}b_{n}=0\]
Out[34]:
\[\tag{${\it \%o}_{83}$}4\,\sum_{n=1}^{\infty }{\frac{\left(-1\right)^{n}\,\cos \left(n\,x\right)}{n^2}}+\frac{\pi^2}{3}\]

求めたフーリエ係数 ans1 を使って,$n = 1, 2, 3, 4$ までのフーリエ級数展開をそれぞれ,F1, F2, F3, F4 として表示してみます。

In [35]:
F1: fourexpand(ans1, x, %pi, 1);
F2: fourexpand(ans1, x, %pi, 2);
F3: fourexpand(ans1, x, %pi, 3);
F4: fourexpand(ans1, x, %pi, 4);
Out[35]:
\[\tag{${\it \%o}_{84}$}\frac{\pi^2}{3}-4\,\cos x\]
Out[35]:
\[\tag{${\it \%o}_{85}$}\cos \left(2\,x\right)-4\,\cos x+\frac{\pi^2}{3}\]
Out[35]:
\[\tag{${\it \%o}_{86}$}-\frac{4\,\cos \left(3\,x\right)}{9}+\cos \left(2\,x\right)-4\,\cos x+\frac{\pi^2}{3}\]
Out[35]:
\[\tag{${\it \%o}_{87}$}\frac{\cos \left(4\,x\right)}{4}-\frac{4\,\cos \left(3\,x\right)}{9}+\cos \left(2\,x\right)-4\,\cos x+\frac{\pi^2}{3}\]

例題

区間 $[-1:1]$ で定義された関数 $f(x) = x$ が,区間外では周期 $2$ の周期関数であるとして,$n=5$ までのフーリエ級数展開を求める。

In [36]:
f0(x):= x;
Out[36]:
\[\tag{${\it \%o}_{88}$}f_{0}\left(x\right):=x\]
In [37]:
/* フーリエ係数を求める */

ans1: fourier(f0(x), x, 1)$
\[\tag{${\it \%t}_{89}$}a_{0}=0\]
\[\tag{${\it \%t}_{90}$}a_{n}=0\]
\[\tag{${\it \%t}_{91}$}b_{n}=-\frac{2\,\left(-1\right)^{n}}{\pi\,n}\]
In [38]:
/* 求めたフーリエ係数を使って n = 5 まで表示 */

F5: fourexpand(ans1, x, 1, 5);
Out[38]:
\[\tag{${\it \%o}_{92}$}\frac{2\,\sin \left(5\,\pi\,x\right)}{5\,\pi}-\frac{\sin \left(4\,\pi\,x\right)}{2\,\pi}+\frac{2\,\sin \left(3\,\pi\,x\right)}{3\,\pi}-\frac{\sin \left(2\,\pi\,x\right)}{\pi}+\frac{2\,\sin \left(\pi\,x\right)}{\pi}\]