Maxima の ctensor を使って球対称な計量から真空のアインシュタイン方程式
$$G^{\mu}_{\ \ \nu} = 0$$
を解き，シュバルツシルト解を求める。
必要なパッケージの load
メトリックが対角的なので，入力の簡便性のために load("diag")$ して diag() を使います。
load(ctensor)$
load(diag)$
球対称な計量
ランダウ・リフシッツ「場の古典論」の記述にそって，球対称な計量を以下のようにおく。（$\lambda$ は予約語？なので $\mu$ にした。）なお，Maxima のリストは 1 始まりなので，第ゼロ成分を第4成分としてみます。
$$ds^2 = e^{\mu(t,r)} dr^2 + r^2 \left(d\theta^2 + \sin^2\theta\,d\phi^2 \right) – e^{\nu(t,r)} dt^2 $$
init_ctensor()$
/* 偏微分表示の簡便性のために */
derivabbrev:true$
/* 次元。デフォルトで 4 */
dim:4$
/* 座標系をリストで */
ct_coords:[r, theta, phi, t];
/* mu(r, t), nu(r, t) */
depends(mu, [r, t])$
depends(nu, [r, t])$
/* g_{\mu\nu} */
lg:diag([exp(mu), r**2, r**2*sin(theta)**2, -exp(nu)]);
/* g^{\mu\nu} を計算させておく */
cmetric()$
アインシュタイン・テンソル
$\displaystyle G^{\mu}_{\ \ \nu} = R^{\mu}_{\ \ \nu} – \frac{1}{2} R \delta^{\mu}_{\ \ \nu} $ = ein
/* アインシュタイン・テンソルの計算。
false で結果を非表示，true ならノンゼロ成分を表示 */
einstein(false)$
アインシュタイン方程式
$$G^{\mu}_{\ \ \nu} = 8\pi G T^{\mu}_{\ \ \nu} – \Lambda \delta^{\mu}_{\ \ \nu} $$
EinEq(a, b):=
(expand(ein[a,b]) = 0);
$\mu$ は時間に依存しないこと
$\displaystyle G^{1}_{\ \ 0}$
EinEq(1, 4);
$\displaystyle G^{1}_{\ \ 0} = 0$ より
$$\mu_t = \frac{\partial \mu}{\partial t} = 0, \quad \therefore\ \ \mu(t, r) \Rightarrow \mu(r)$$
$\mu(r)$ として，あらためてアインシュタイン・テンソルを求めてみる。
init_ctensor()$
/* 偏微分表示の簡便性のために */
derivabbrev:true$
/* 次元。デフォルトで 4 */
dim:4$
/* 座標系をリストで */
ct_coords:[r, theta, phi, t]$
/* mu(r), nu(r, t) */
depends(mu, [r])$
depends(nu, [r, t])$
/* g_{\mu\nu} */
lg:diag([exp(mu), r**2, r**2*sin(theta)**2, -exp(nu)])$
/* g^{\mu\nu} を計算させておく */
cmetric()$
/* アインシュタイン・テンソルの計算。
false で結果を非表示，true ならノンゼロ成分を表示 */
einstein(false)$
$\displaystyle G^{0}_{\ \ 0} = 0$
EinEq(4, 4);
$\displaystyle G^{1}_{\ \ 1} = 0$
EinEq(1, 1);
$\displaystyle G^{2}_{\ \ 2} = 0$
EinEq(2, 2);
$\displaystyle G^{3}_{\ \ 3} = 0$
EinEq(3, 3);
$\displaystyle G^{2}_{\ \ 2} = \displaystyle G^{3}_{\ \ 3}$ であることを確認。$\displaystyle G^{2}_{\ \ 2} – \displaystyle G^{3}_{\ \ 3}$ がゼロとなることを示す。
ein[2,2] - ein[3,3];
$\nu = – \mu$ とおけること
EinEq(1, 1) - EinEq(4, 4);
% * r * exp(mu), expand;
$G^1_{\ \ 1} – G^2_{\ \ 2} = 0$ より，以下の式が得られる。
$$\nu_r + \mu_r = \frac{\partial}{\partial r}\left(\nu(t, r) + \mu(r)\right) = 0$$
これから，$f(t)$ を積分「定数」として
$$\nu(t, r) = – \mu(r) + f(t)$$
となる。
\begin{eqnarray}
\therefore\ \ e^{\nu(t, r)} dt^2 &=& e^{- \mu(r) + f(t)} dt^2 \\
&=& e^{- \mu(r)} \left( e^{\frac{f(t)}{2}} dt\right)^2
\end{eqnarray}
時間 $t$ のみの任意関数 $f(t)$ の自由度は，$e^{\frac{f(t)}{2}} dt \Rightarrow dt’$ なる新しい時間座標の定義によって吸収できるので，一般性を失うことなく $f(t) = 0$ すなわち
$$\nu(t, r) = – \mu(r)$$
とすることができる。
バーコフの定理
ここまでは，球対称真空解は metric が時間によらない，つまり静的であるということを示しているわけで，バーコフの定理の証明になっている。バーコフの定理のもう一つの帰結である漸近的平坦性については，以下で示すように解が $e^{-\mu(r)} = \displaystyle 1 – \frac{r_g}{r}$ となることで $r \rightarrow \infty$ で $e^{-\mu(r)} \rightarrow 1$ となることからわかる。
ということで，あらためて以下のような計量テンソルに対して，アインシュタイン・テンソルを計算してみる。
init_ctensor()$
/* 偏微分表示の簡便性のために */
derivabbrev:true$
/* 次元。デフォルトで 4 */
dim:4$
/* 座標系をリストで */
ct_coords:[r, theta, phi, t]$
/* mu(r) */
depends(mu, [r]);
/* g_{\mu\nu} */
lg:diag([exp(mu), r**2, r**2*sin(theta)**2, -exp(-mu)]);
/* g^{\mu\nu} を計算させておく */
cmetric()$
/* アインシュタイン・テンソルの計算。
false で結果を非表示，true ならノンゼロ成分を表示 */
einstein(false)$
EinEq(4, 4);
eq: EinEq(4, 4) * r**2, expand;
微分方程式を解き，$\mu$ を求める
微分方程式 $\displaystyle – e^{-\mu} \frac{d\mu}{d r} r + e^{-\mu} – 1 = 0$ を Maxima の ode2() を使って解く。
sol: ode2(eq, mu, r);
これでは今ひとつ。$\mu(r)$ について解いたことになっていない。$f(r) \equiv e^{-\mu(r)}$ とおくと，
$$- e^{-\mu} \frac{d\mu}{d r} r + e^{-\mu} – 1 = \frac{df}{dr} r + f -1 = 0$$
となるのでこっちを解いてみる。
depends(f, r)$
eq2: 'diff(f, r) * r + f -1 = 0$
ode2(eq2, f, r), expand;
積分定数 $\%c$ はニュートン近似のときに，
\begin{eqnarray}
g_{00} = g_{44} &=& – e^{-\mu} \\
&\simeq& – \left( 1 + 2 \frac{\phi}{c^2}\right) \\
&=& – \left( 1 – 2 \frac{GM}{r c^2}\right)
\end{eqnarray}
となることから，
$$\%c = -\frac{2 GM}{c^2} \equiv -r_g$$
となる。
最終的に
$$ds^2 = \frac{dr^2}{1 – \frac{r_g}{r}} + r^2 \left(d\theta^2 + \sin^2\theta \,d\phi^2 \right) -\left(1 – \frac{r_g}{r} \right) dt^2$$