導出については，以下のページ：
$t = 0$ からの $a(t)$ の立ち上がりを揃えたグラフの例
異なる $\Omega_{\rm m}$ の場合のスケール因子の時間変化のグラフを，$t=0$ でのスケール因子 $a(t)$ の傾きを揃えて描く場合。同じようにビッグバンで始まった宇宙の膨張が，$\Omega_{\rm m}$ の値によってその後の膨張の仕方に違いがあらわれ，ある場合には途中で膨張が止まって収縮に転じたり，ある場合には永久に膨張が続いたりするんだなぁ… ということを理解するのに適切なグラフ。
$\Omega_{\Lambda} = 0, \Omega_{\rm m} > 1$ すなわち $k > 0$ の場合
$\Omega_{\rm m} \rightarrow \Omega$ として
\begin{eqnarray}
a_1(u, \Omega) = \frac{a}{a_0}
&=& \frac{\Omega}{2 (\Omega -1)}
\left(1 -\cos\left(\sqrt{\Omega-1} u\right)\right)\\
t_1(u, \Omega) = H_0 t &=& \frac{\Omega}{2 (\Omega -1) }
\left(u -\frac{\sin\left(\sqrt{\Omega-1} u\right)}{\sqrt{\Omega-1}}\right)
\end{eqnarray}
となりそうだが，$|u| \ll 1$ での振るまいが後述の $\Omega_{\rm m} = 1$ の場合のように（$\Omega$ の値によらずに）
\begin{eqnarray}
a_1 &\simeq& \frac{u^2}{4} \\
t_1 &\simeq& \frac{u^3}{12}
\end{eqnarray}
となるためには，以下のように縦横等倍で縮尺を変えてやればよい。
\begin{eqnarray}
a_1(u, \Omega) \equiv \frac{a}{a_0} \times \Omega^{-1}
&=& \frac{1}{2 (\Omega -1)}
\left(1 -\cos\left(\sqrt{\Omega-1} u\right)\right)\\
t_1(u, \Omega) \equiv H_0 t \times \Omega^{-1}&=& \frac{1}{2 (\Omega -1) }
\left(u -\frac{\sin\left(\sqrt{\Omega-1} u\right)}{\sqrt{\Omega-1}}\right)
\end{eqnarray}
a1(u, Omega):= 1/(2*(Omega-1)) * (1 - cos(sqrt(Omega -1) * u));
t1(u, Omega):= 1/(2*(Omega-1)) * (u - sin(sqrt(Omega -1) * u)/sqrt(Omega -1));
$\Omega_{\Lambda} = 0, \Omega_{\rm m} < 1$ すなわち $k < 0$ の場合
同様に
\begin{eqnarray}
a_2(u, \Omega) \equiv \frac{a}{a_0}\times \Omega^{-1}
&=& \frac{1}{2 (1-\Omega)}
\left(\cosh\left(\sqrt{1-\Omega} u\right) -1\right)
\\
t_2(u, \Omega) \equiv H_0 t \times \Omega^{-1}&=& \frac{1}{2 (1 -\Omega) }
\left(\frac{\sinh\left(\sqrt{1-\Omega} u\right)}{\sqrt{1-\Omega}}- u\right)
\end{eqnarray}
a2(u, Omega):= 1/(2*(1-Omega)) * (cosh(sqrt(1-Omega) * u)-1);
t2(u, Omega):= 1/(2*(1-Omega)) * (sinh(sqrt(1-Omega) * u)/sqrt(1-Omega) - u);
$\Omega_{\Lambda} = 0, \Omega_{\rm m} = 1$ すなわち $k = 0$ の場合
\begin{eqnarray}
a_3(u) \equiv \lim_{\Omega\rightarrow 1} a_1(u, \Omega) &=& \frac{u^2}{4} \\
t_3(u) \equiv \lim_{\Omega\rightarrow 1} t_1(u, \Omega) &=& \frac{u^3}{12}
\end{eqnarray}
'limit('a1(u, Omega), Omega, 1) =
limit(a1(u, Omega), Omega, 1);
'limit('t1(u, Omega), Omega, 1) =
limit(t1(u, Omega), Omega, 1);
define(a3(u), limit(a1(u, Omega), Omega, 1));
define(t3(u), limit(t1(u, Omega), Omega, 1));
Omega1: 1.1$
Omega2: 0.9$
u1: 2*%pi/sqrt(Omega1 -1)$
/* */
trange: t1(u1, Omega1)$
draw2d(
/* フォント設定 */
font = "Arial", font_size = 14,
/* 凡例の位置 */
user_preamble = "set key left top;",
/* 滑らかにするためにサンプリングを多めに */
nticks = 100,
/* 横軸縦軸の表示範囲 */
xrange = [0, trange*1.02], yrange = [0, 42],
/* 軸の目盛なしに */
xtics = false, ytics = false,
/* フォント設定はお好みで... */
xlabel = "{/jsMath-cmti10=16 t}",
ylabel = "{/jsMath-cmti10=16 a(t)}",
line_width = 2,
color = blue,
label(["{/Times=16 Ω_m < 1}", 80, 32]),
parametric(t2(u, Omega2), a2(u, Omega2), u, 0, u1),
color = black,
label(["{/Times=16 Ω_m = 1}", 80, 22]),
parametric(t3(u), a3(u), u, 0, u1),
color = red,
label(["{/Times=16 Ω_m > 1}", 80, 10]),
parametric(t1(u, Omega1), a1(u, Omega1), u, 0, u1)
)$
$t = t_0$ で $a(t_0)$ と $H_0 = \frac{\dot{a}}{a}|_{t_0}$ を揃えたグラフの例
異なる $\Omega_{\rm m}$ の場合のスケール因子の時間変化のグラフを，現在時刻 $t=t_0$ でのスケール因子 $a(t)$ の傾きを揃えて描く場合。現在時刻でのスケール因子の傾きを表すハッブル定数 $H_0$ の値が同じでも，時間を遡るとやがて $a(t)$ がゼロになる時刻すなわち宇宙年齢が異なるのだなぁ… ということを理解するのに便利なグラフ。
$\Omega_{\Lambda} = 0, \Omega_{\rm m} > 1$ すなわち $k > 0$ の場合
\begin{eqnarray}
\frac{a}{a_0} \equiv x
&=& \frac{\Omega_{\rm m}}{2 (\Omega_{\rm m} -1)}
\left(1 -\cos\left(\sqrt{k} \eta\right)\right)
\\
H_0 t &=& \frac{\Omega_{\rm m}}{2 (\Omega_{\rm m} -1)^{\frac{3}{2}} }
\left(\sqrt{k} \eta -\sin\left(\sqrt{k} \eta\right)\right)
\end{eqnarray}
これから
\begin{eqnarray}
\cos\sqrt{k} \eta &=& 1 – \frac{2 (\Omega_{\rm m} -1)}{\Omega_{\rm m}}x\\
\sqrt{k} \eta &=& \cos^{-1} \left(1 – \frac{2 (\Omega_{\rm m} -1)}{\Omega_{\rm m}}x \right)
\end{eqnarray}
$\Omega_{\rm m} \rightarrow \Omega$ として
\begin{eqnarray}
\therefore\ \ T_1(x, \Omega) &\equiv& H_0 t = \frac{\Omega}{2 (\Omega -1)^{\frac{3}{2}} }
\left(\sqrt{k} \eta -\sin \sqrt{k} \eta \right) \\
&=& \frac{\Omega}{2 (\Omega -1)^{\frac{3}{2}} }
\left(\cos^{-1} \left(1 – \frac{2 (\Omega -1)}{\Omega} x \right)
– \sqrt{1 – \left(1 – \frac{2 (\Omega -1)}{\Omega} x \right)^2} \right)
\end{eqnarray}
として，$H_0 t$ を $x$ で表す。
T1(x, Omega):= Omega/(2*(Omega-1)*sqrt(Omega-1)) *
(acos(1 - 2*(Omega-1)/Omega * x) - sqrt(1-(1-2*(Omega-1)/Omega * x)**2));
$\Omega_{\Lambda} = 0, \Omega_{\rm m} < 1$ すなわち $k < 0$ の場合
\begin{eqnarray}
\frac{a}{a_0} \equiv x
&=&\frac{\Omega_{\rm m}}{2 (1-\Omega_{\rm m} )}
\left(\cosh \sqrt{k} \eta -1\right)
\end{eqnarray}
これから
\begin{eqnarray}
\cosh\sqrt{k} \eta &=& 1 + \frac{2 (1-\Omega_{\rm m})}{\Omega_{\rm m}}x \\
\sqrt{k} \eta &=& \cosh^{-1} \left(1 + \frac{2 (1-\Omega_{\rm m})}{\Omega_{\rm m}}x\right)
\end{eqnarray}
$\Omega_{\rm m} \rightarrow \Omega$ として
\begin{eqnarray}
\therefore\ \
T_2(x, \Omega) &\equiv& H_0 t = \frac{\Omega}{2 (1-\Omega)^{\frac{3}{2}} }
\left(\sinh \sqrt{k} \eta – \sqrt{k} \eta \right) \\
&=& \frac{\Omega}{2 (1-\Omega)^{\frac{3}{2}} }
\left(
\sqrt{\left(1 + \frac{2 (1-\Omega)}{\Omega}x \right)^2 – 1} –
\cosh^{-1} \left(1 + \frac{2 (1-\Omega)}{\Omega}x\right) \right)
\end{eqnarray}
として，$H_0 t$ を $x$ で表す。
T2(x, Omega):= Omega/(2*(1-Omega)*sqrt(1-Omega)) *
(sqrt((1+2*(1-Omega)/Omega * x)**2 -1) -acosh(1 + 2*(1-Omega)/Omega * x));
$\Omega_{\Lambda} = 0, \Omega_{\rm m} = 1$ すなわち $k = 0$ の場合
\begin{eqnarray}
\frac{a}{a_0} = x &=& \left(\frac{3}{2}H_0 t \right)^{\frac{2}{3}}
\end{eqnarray}$$\therefore\ \ T_3(x) \equiv H_0 t = \frac{2}{3} x^{\frac{3}{2}}$$
T3(x):= 2/3 * x*sqrt(x);
draw2d(
/* フォント設定 */
font = "Arial", font_size = 14,
/* 凡例の位置，主目盛・副目盛の設定 */
user_preamble = "set key right bottom; set key sample 1;
set xtics mirror; set ytics mirror;
set xtics 0.5; set mxtics 5;
set ytics 0.5; set mytics 5; set grid;",
/* 滑らかにするためにサンプリングを多めに */
nticks = 100,
/* 横軸縦軸の表示範囲 */
xrange = [-1, 1.6], yrange = [0, 3],
title = "{/Times=16 Ω_Λ = 0 の場合のスケール因子の時間発展}",
xlabel = "{/Times:Italic=16 H_0 (t - t_0)}",
ylabel = "{/jsMath-cmti10=16 a(t)/a_0}",
line_type = solid,
line_width = 2,
color = blue, key = "{/Times=16 Ω_m = 0.3}",
parametric(T2(x, 0.3)-T2(1, 0.3), x, x, 0, 3),
color = black, key = "{/Times=16 Ω_m = 1.0}",
parametric(T3(x) - T3(1), x, x, 0, 3),
color = red, key = "{/Times=16 Ω_m = 2.0}",
parametric(T1(x, 2)-T1(1, 2), x, x, 0, 2)
)$
$k = 0$ の場合
宇宙定数がある場合のスケール因子の時間変化についても追加しておく。
$k = 0, \ 0<\Omega_{\rm m} < 1$ つまり $\Omega_{\Lambda} > 0$ の場合
\begin{eqnarray}
\frac{a}{a_0} = x &=&
\left\{\sqrt{\frac{\Omega_{\rm m}}{1-\Omega_{\rm m}}}
\sinh\left(\frac{3\sqrt{1-\Omega_{\rm m}}}{2} H_0 t\right)\right\}^{\frac{2}{3}} \end{eqnarray}
より $\Omega_{\rm m} \rightarrow \Omega$ として
$$T_3(x, \Omega) \equiv H_0 t = \frac{2}{3\sqrt{1-\Omega}}
\sinh^{-1} \left( \sqrt{\frac{1-\Omega}{\Omega}} x^{\frac{3}{2}}\right)$$
T4(x, Omega):= 2/(3*sqrt(1-Omega)) * asinh(sqrt((1-Omega)/Omega) * x*sqrt(x));
draw2d(
/* フォント設定 */
font = "Arial", font_size = 14,
/* 凡例の位置，主目盛・副目盛の設定 */
user_preamble = "set key right bottom; set key sample 1;
set xtics mirror; set ytics mirror;
set xtics 0.5; set mxtics 5;
set ytics 0.5; set mytics 5; set grid;",
/* 滑らかにするためにサンプリングを多めに */
nticks = 100,
/* 横軸縦軸の表示範囲 */
xrange = [-1, 1.6], yrange = [0, 4],
title = "{/Times=16 スケール因子の時間発展}",
xlabel = "{/Times:Italic=16 H_0 (t - t_0)}",
ylabel = "{/jsMath-cmti10=16 a(t)/a_0}",
line_type = solid,
line_width = 2,
color = violet, key = "{/Times=16 Ω_m = 0.3, Ω_Λ = 0.7}",
parametric(T4(x, 0.3)-T4(1, 0.3), x, x, 0, 4),
color = blue, key = "{/Times=16 Ω_m = 0.3, Ω_Λ = 0.0}",
parametric(T2(x, 0.3)-T2(1, 0.3), x, x, 0, 3),
color = black, key = "{/Times=16 Ω_m = 1.0, Ω_Λ = 0.0}",
parametric(T3(x) - T3(1), x, x, 0, 3),
color = red, key = "{/Times=16 Ω_m = 2.0, Ω_Λ = 0.0}",
parametric(T1(x, 2)-T1(1, 2), x, x, 0, 2)
)$
