In [1]:
%gnuplot inline svg size 600,450 font "Arial, 14"
$\Omega_{\Lambda} = 0$ の場合
$$H_0 t_0 = -\frac{1}{\Omega_{\rm m} -1}+\frac{\Omega_{\rm m}}{(\Omega_{\rm m}-1)^{\frac{3}{2}} }
\tan^{-1}\sqrt{\Omega_{\rm m}-1} \quad \mbox{for}\ \ \Omega_{\rm m} > 1$$$$H_0 t_0 = \frac{1}{1-\Omega_{\rm m}}-\frac{\Omega_{\rm m}}{(1-\Omega_{\rm m})^{\frac{3}{2}} }
\tanh^{-1}\sqrt{1-\Omega_{\rm m}} \quad \mbox{for}\ \ \Omega_{\rm m} < 1$$
In [2]:
# Omega > 1
t1(Om) = -1./(Om-1) + Om/((Om-1)*sqrt(Om-1)) * atan(sqrt(Om-1))
# Omega < 1
t2(Om) = 1./(1-Om) - Om/((1-Om)*sqrt(1-Om)) * atanh(sqrt(1-Om))
# 三項演算子を使った関数定義。Om = 1 のときがちょっと不安
t(Om) = (Om > 1 ? t1(Om) : t2(Om))
$k = 0$ の場合
$$H_0 t_0 = \frac{2}{3\sqrt{\Omega_{\rm m} -1}}\tan^{-1} \sqrt{\Omega_{\rm m} -1} \quad \mbox{for}\ \ \Omega_{\rm m} > 1$$$$H_0 t_0 = \frac{2}{3\sqrt{1-\Omega_{\rm m} }}\tanh^{-1} \sqrt{1-\Omega_{\rm m} } \quad \mbox{for}\ \ \Omega_{\rm m} < 1$$
In [3]:
# Omega > 1
T1(Om) = 2./(3*sqrt(Om-1)) * atan(sqrt(Om-1))
# Omega < 1
T2(Om) = 2./(3*sqrt(1-Om)) * atanh(sqrt(1-Om))
# 三項演算子を使った関数定義。Om = 1 のときがちょっと不安
T(Om) = (Om > 1 ? T1(Om) : T2(Om))
In [4]:
set samples 200
set title "宇宙年齢の密度パラメータ依存性"
set xlabel "{/Times Ω_m}"
set ylabel "{/jsMath-cmti10=16 H}_0 {/jsMath-cmti10=16 t}_0"
set xtics 0.2
set mxtics 2
set ytics 0.1
set mytics 2
set grid
set yrange [0.5:1.5]
plot [Om=0:2] \
T(Om) lc "red" lw 2 title "{/Times Ω_Λ = 1 - Ω_m}", \
t(Om) lc "black" lw 2 title "{/Times Ω_Λ = 0}"
