円運動する観測者の時間の進み方

シュバルツシルト時空において，

• \(r = r_1 (=R)\) （地上を想定）に静止している時計の進みを \(\varDelta \tau_1\)
• 上空を半径 \(r (> R)\) の円軌道を描いて運動する時計の進みを \(\varDelta \bar{\tau}\)
• 動径座標 \(r\)に静止している時計の進みを \(\varDelta \tau\)

とする。

このとき，半径 \(r (> R)\) の円軌道を描いて運動する時計の進み \(\varDelta \bar{\tau}\) と，地上 \(r = r_1 ( = R)\) に静止し続けている時計の進み \(\varDelta \tau_1\) の比 \(\displaystyle \frac{\varDelta \bar{\tau}}{\varDelta \tau_1}\) はどうなるか，という話。

異なる地点に静止している時計の進みの比

まず， 異なる地点に静止している時計の進み方の比は，既に説明したように

$$\frac{\varDelta \tau}{\varDelta \tau_1} = \frac{\sqrt{1 – \frac{r_g}{r}}}{\sqrt{1 – \frac{r_g}{r_1}}} $$

ローレンツ因子

次に，同じ動径座標 \(r\) に静止している時計の進み \(\varDelta \tau\) と，速さ \(V\) で運動している時計の進み \(\varDelta \bar{\tau}\) は，特殊相対論の場合と同様に一般相対論的状況下においても，ローレンツ因子の逆数である \(\sqrt{1 – V^2}\) だけ異なるはずである。（\(c = 1\)）

静止観測者からみた，円運動する観測者に関するローレンツ因子 \(\gamma\) は

$$\gamma\equiv \frac{1}{\sqrt{1-V^2}} =  \frac{\sqrt{1 – \frac{r_g}{r}}}{\sqrt{1 – \frac{3}{2}\frac{r_g}{r}}}$$

であったから，

$$ \frac{\varDelta \bar{\tau}} {\varDelta \tau} = \sqrt{1 – V^2} = \frac{\sqrt{1 – \frac{3}{2}\frac{r_g}{r}}}{\sqrt{1 – \frac{r_g}{r}}}$$

静止観測者からみた円運動する時計の進み

ということで，最終的には

$$ \frac{\varDelta \bar{\tau}}{\varDelta \tau_1} = \frac{\varDelta \tau}{\varDelta \tau_1} \frac{\varDelta \bar{\tau}} {\varDelta \tau} = \frac{\sqrt{1 – \frac{r_g}{r}}}{\sqrt{1 – \frac{r_g}{r_1}}}  \frac{\sqrt{1 – \frac{3}{2}\frac{r_g}{r}}}{\sqrt{1 – \frac{r_g}{r}}} =
\frac{\sqrt{1 – \frac{3}{2}\frac{r_g}{r}}}{\sqrt{1 – \frac{r_g}{r_1}}} $$

この式から上空を運動している人工衛星や国際宇宙ステーションの時計は，地上の時計と比べて必ずしも進むだけだったり，また遅れるだけだったりではないということがわかる。上記には，より上空の重力ポテンシャルの浅い場所にあることによる時計を進ませる効果と，運動していることにより時計を遅れさせる効果の両方が入っている。

\(r = r_1 \gg r_g\) に静止している観測者からみていると，円軌道の半径 \(r\) が小さくなればなるほど，この円運動する時計の進み \(\varDelta \bar{\tau}\) は小さく・ゆっくりになっていき，\(\displaystyle r \rightarrow \frac{3}{2} r_g = \frac{3GM}{c^2}\) で \(\varDelta \bar{\tau} \rightarrow 0\) となる。

Maxima-Jupyter による計算例

Dtratio: sqrt((1-3/2*rg/r)/(1-rg/r1));

solve(Dtratio = 1, r);

Dtratio1: taylor(Dtratio, rg, 0, 1);

delta: Dtratio1 - 1;

/* 地球半径 */
r1: 6378E3;

G: 6.674E-11$
/* 地球質量 */
M: 5.972E24$
/* 光速 */
c: 299792458$
/* 地球の重力半径 */
rg: 2*G*M/c**2$

/* ISS の軌道半径，約410km上空 */
r: r1 + 410.0E3;

/* 有効桁を 2桁くらいで表示させる */
fpprintprec: 2$
ans: ev(delta)*60*60*24*365.25, float$

if ans > 0 then
    print("ISS の時計は 1 年あたり", abs(ans), "秒 進む。")
  else
    print("ISS の時計は 1 年あたり", abs(ans), "秒 遅れる。")$

/* GPS 衛星の軌道半径。高度 20,200 km */
r: r1 + 20200E3$
/* 1秒あたりのオフセットは */
fpprintprec: 0$
ev(delta), float;

/* 1日あたりにすると */
fpprintprec: 4$
ans: ev(delta)*60*60*24, float$

if ans > 0 then
    print("GPS 衛星の時計は 1 日あたり", abs(ans), "秒 進む。")
  else
    print("GPS 衛星の時計は 1 日あたり", abs(ans), "秒 遅れる。")$

fpprintprec: 0$
Ve: float(2*%pi*r1/(24*60*60));
(Ve/c)**2;